Pushbutton

The DDS for the printer pop-up menu display screen 
     A*%%TS  SD  19991104  104451  BOOTH       REL-V4R4M0  5769-PW1             
     A*%%EC                                                                     
     A                                      DSPSIZ(24 80 *DS3)                  
     A                                      CSRINPONLY                          
     A                                      ERRSFL                              
     A*                                                                         
     A          R FMT01                                                         
     A*%%TS  SD  19980507  182807  BOOTH       REL-V4R2M0  5769-PW1             
     A                                      TEXT('PRINTER CONTROL MENU')        
     A                                      CF03(03 'EXIT')                     
     A                                      CF06(06 'MESSAGE')                  
     A                                      OVERLAY                             
     A                                      WINDOW(*DFT 10 26 *NOMSGLIN)        
     A                                      WDWTITLE((*TEXT ' Printer Control M-
     A                                      enu '))                             
     A                                  1  1'User   '                           
     A            FIELDU        10A  B  1  9DSPATR(UL)                          
     A                                      COLOR(WHT)                          
     A                                  2  1'Printer'                           
     A            FIELDP        10A  B  2  9DSPATR(UL)                           
     A                                      COLOR(WHT)                           
     A            PB1            2Y 0B  4  1PSHBTNFLD                            
     A                                      PSHBTNCHC(1 'Start Print W>riter  ') 
     A                                      PSHBTNCHC(2 'Display Output Q>ueue') 
     A                                      PSHBTNCHC(3 'Display P>rinter Messa- 
     A                                      ges')                                
     A                                      PSHBTNCHC(4 'Display S>pool File  ') 
     A                                      CHCAVAIL((*COLOR BLU))               
     A            PB2            2Y 0B  9  1PSHBTNFLD((*GUTTER 1))               
     A                                      PSHBTNCHC(1 'E>xit' CF03)            
     A                                      PSHBTNCHC(2 'M>essages' CF06)        
     A                                      CHCAVAIL((*COLOR BLU))               
     A          R DUMMY                                                          
     A                                      TEXT('PREVENTS PREVIOUS SCREEN FROM- 
     A                                       BEING CLEARED')                     
     A                                      ASSUME                               
     A                                  5  9' '






The CL to provide the functions of the popup menu

PGM                                                              
             DCLF       FILE(P1P0FM)                             
             DCL        VAR(&USER) TYPE(*CHAR) LEN(10)           
             MONMSG (CPF0000)                                    
             RTVJOBA    USER(&USER) PRTDEV(&FIELDP)              
             CHGVAR &FIELDU VALUE(&USER)                         
                                                                 
START:                                                           
/* Did user choose to exit?         */                           
             IF         COND(&PB2 *EQ 1) THEN(RETURN)            
             IF         COND(&PB2 *EQ 2) THEN(DSPMSG)            
                                                                 
             IF         COND(&FIELDP *EQ ' ') THEN(CHGVAR +      
                          VAR(&FIELDP) VALUE(*OUTQ))             
             SNDRCVF    DEV(*FILE) RCDFMT(FMT01) WAIT(*YES)      
             RMVMSG     CLEAR(*ALL)                              
                                                                 
             IF         COND(&IN03) THEN(DO)                     
             IF         COND(&USER *EQ '&FIELDP') THEN(SIGNOFF)                 
             RETURN                                
             ENDDO                                 
                                                   
/* F6-DISPLAY MESSAGES     */                      
             IF         COND(&IN06) THEN(DSPMSG)   
                                                   
/* START PRINT WRITER &FIELDP */                   
             IF         COND(&PB1 *EQ 1) THEN(DO)  
             STRPRTWTR  DEV(&FIELDP) OUTQ(&FIELDP) 
             MONMSG     MSGID(CPF3310)             
             ENDDO                                 
                                                   
/* DISPLAY OUTPUT QUEUE &FIELDP   */               
             IF         COND(&PB1 *EQ 2) THEN(DO)  
             WRKOUTQ    OUTQ(&FIELDP)              
             ENDDO                                 
                                                   
/* DISPLAY PRINTER MESSAGES &FIELDP */             
             IF         COND(&PB1 *EQ 3) THEN(DO)  
             DSPMSG     MSGQ(&FIELDP)              
             ENDDO                                
                                                  
/* DISPLAY spool file       &FIELDP */            
             IF         COND(&PB1 *EQ 4) THEN(DO) 
             WRKSPLF    SELECT(&FIELDU &FIELDP)   
             ENDDO                                
                                                  
             GOTO       CMDLBL(START)             
                                                  
 ENDPGM